Zu den Funktionen für Beträge und Währungen gehört die Funktion loadCurrency, um eine Währung zu öffnen.

Allgemeine Informationen zu den OLTP-Funktionen der System-Skriptsprache erhalten Sie im Artikel System-Skriptsprache: OLTP-Funktionen.

loadCurrency

Folgendes Beispiel aus der Aktivitätsdefinition help.loadCurrency öffnet eine Währung über dessen ISO-Code und gibt die Bezeichnung zurück.

function create()
{
var p_isoCode := parameters.ISO_CODE;
var r_currency := loadCurrency(p_isoCode);

result.IS_NULL := isNull(r_currency);
if (not isNull(r_currency))
result.DESCRIPTION := r_currency:description;
}

Weitere Funktionsdeklarationen für Beträge und Währungen

Dieses Kapitel schlägt weitere Funktionsdeklarationen für Beträge und Währungen vor, die Sie in Ihrem System erfassen und verwenden können. Die Funktionsdeklarationen sind ohne Gewähr und dienen in erster Linie dem Erlernen der System-Skriptsprache.

• amountCorporate
• convertCurrency
• getCorporateCurrency
• getCurrency1
• getCurrency2
• getCurrency3

amountCorporate

amountCorporate(
parameters.object:totalValues.netValueDomestic.
amount1,parameters.object:totalValues.netValueDomestic.amount2, parameters.object:totalValues.
netValueDomestic.amount3, cast(Guid, getAttribute(parameters.object, "_organization")))

Folgendes Beispiel aus der Aktivitätsdefinition help.amountCorporate zeigt, wie aus einem aus bis zu drei Hauswährungen bestehenden Hauswährungsbetrag der Betrag in der Leitwährung der Firma bestimmt werden kann.

function create()
{
var p_orderType := parameters.ORDER_TYPE;
var p_orderNumber := parameters.ORDER_NUMBER;

var orderType := getByBusinessKey(CisObject(com.cisag.app.sales.obj.SalesOrderType), p_orderType);
var order := getByBusinessKey(CisObject(com.cisag.app.sales.obj.SalesOrder), orderType:guid, p_orderNumber);
var totalGrossValueCorporate := amountCorporate(
order:totalValues.grossValueDomestic.amount1,
order:totalValues.grossValueDomestic.amount2,
order:totalValues.grossValueDomestic.amount3,
cast(Guid, getAttribute(order, "_organization")));

result.VALUE := totalGrossValueCorporate;
}

function amountCorporate(amount1 as Number, amount2 as Number, amount3 as Number, org as Guid) as Number
{
var amountCorporate := 0;
var baseFunction := getCustomizingValue("com.cisag.app.general.Base", loadOrganization(org):financialsOrganization);

if (not isNull(baseFunction)) {
if (baseFunction:corporateCurrency = 1)
amountCorporate := amount1;
if (baseFunction:corporateCurrency = 2)
amountCorporate := amount2;
if (baseFunction:corporateCurrency = 3)
amountCorporate := amount3;
}
return amountCorporate;
}

function amountCorporate2(domesticAmount as CisObject(com.cisag.app.general.obj.DomesticAmount), org as Guid) as Number
{
var amountCorporate := 0;
var baseFunction := getCustomizingValue("com.cisag.app.general.Base", loadOrganization(org):financialsOrganization);

if (not isNull(baseFunction)) {
if (baseFunction:corporateCurrency = 1)
amountCorporate := domesticAmount:amount1;
if (baseFunction:corporateCurrency = 2)
amountCorporate := domesticAmount:amount2;
if (baseFunction:corporateCurrency = 3)
amountCorporate := domesticAmount:amount3;
}
return amountCorporate;
}

convertCurrency

Folgendes Beispiel aus der Aktivitätsdefinition help.convertCurrency zeigt, wie ein Betrag zwischen zwei Währungen umgerechnet werden kann. Die Funktion convertCurrency rechnet einen Betrag zu den aktuell gültigen Wechselkursen um, wobei die Funktion convertCurrenncyAt auch historische Wechselkurse verwendet.

const ExchangeRateQuotation as valueSet(com.cisag.app.general.ExchangeRateQuotation);

function create()
{
var p_amount := parameters.AMOUNT;
var p_source := parameters.SOURCE;
var p_target := parameters.TARGET;
var p_conversionDate := parameters.CONVERSION_DATE;
var r_convertedAmountAt := 0;

var convertedAmountAt := convertCurrencyAt(p_amount, loadCurrency(p_source):guid, loadCurrency(p_target):guid, p_conversionDate);
if (not isNull(convertedAmountAt))
r_convertedAmountAt := convertedAmountAt;

result.IS_NULL := isNull(r_convertedAmountAt);
result.CONVERTED_AMOUNT := r_convertedAmountAt;
}

function convertCurrency(amount as Number, sourceCurrency as Guid, targetCurrency as Guid) as Number
{
var convertedAmount := 0;
var useReverseQuotation := false;
var company := cast(Guid, getCustomizingValue("com.cisag.app.General"):company);
var exchangeRateUse := cast(Guid, getCustomizingValue("com.cisag.app.general.Base", company):exchangeRateUse);
var quotation := getCustomizingValue("com.cisag.app.general.Base", company):exchangeRateQuotation;
var factor := 1;

var exchangeRate := getByBusinessKey(CisObject(com.cisag.app.general.obj.ExchangeRate), exchangeRateUse, sourceCurrency, targetCurrency);
if (isNull(exchangeRate)) {
exchangeRate := getByBusinessKey(CisObject(com.cisag.app.general.obj.ExchangeRate), exchangeRateUse, targetCurrency, sourceCurrency);
useReverseQuotation := true;
}
if (not isNull(exchangeRate)) {
if (exchangeRate:factor = 2) factor := 10;
if (exchangeRate:factor = 3) factor := 100;
if (exchangeRate:factor = 4) factor := 1000;
if (exchangeRate:factor = 5) factor := 10000;
if ((useReverseQuotation = false and quotation = ExchangeRateQuotation.DIRECT) or
(useReverseQuotation = true and quotation = ExchangeRateQuotation.INDIRECT))
convertedAmount := (amount * factor) / exchangeRate:middleRate;
else
convertedAmount := (amount * exchangeRate:middleRate) / factor;
}
return convertedAmount;
}

function convertCurrencyAt(amount as Number, sourceCurrency as Guid, targetCurrency as Guid, conversionDate as Timestamp) as Number
{
var convertedAmount := 0;
var useReverseQuotation := false;
var company := cast(Guid, getCustomizingValue("com.cisag.app.General"):company);
var exchangeRateUse := cast(Guid, getCustomizingValue("com.cisag.app.general.Base", company):exchangeRateUse);
var quotation := getCustomizingValue("com.cisag.app.general.Base", company):exchangeRateQuotation;
var factor := 1;

var OQL :=
"SELECT FROM com.cisag.app.general.obj.ExchangeRate o " +
"WHERE o:exchangeRateUse = ? AND o:sourceCurrency = ? AND o:targetCurrency = ? " +
" AND o:validFrom <= toTimeStamp(„" + timeZoneId(today()) + "„, " +
format(year(conversionDate)) + ", " + format(month(conversionDate)) + ", " + format(day(conversionDate)) + ", " +
format(hour(conversionDate)) + ", " + format(minute(conversionDate)) + ", " + format(second(conversionDate)) + ", " +
format(millisecond(conversionDate)) + ") " +
" AND o:validUntil > toTimeStamp(„" + timeZoneId(today()) + "„, " +
format(year(conversionDate)) + ", " + format(month(conversionDate)) + ", " + format(day(conversionDate)) + ", " +
format(hour(conversionDate)) + ", " + format(minute(conversionDate)) + ", " + format(second(conversionDate)) + ", " +
format(millisecond(conversionDate)) + ")";
var oList := getCisObjectList("OLTP", OQL, list(exchangeRateUse, sourceCurrency, targetCurrency), 1);
if (size(oList) = 0) {
oList := getCisObjectList("OLTP", OQL, list(exchangeRateUse, targetCurrency, sourceCurrency), 1);
useReverseQuotation := true;
}
for (exchangeRate as CisObject(com.cisag.app.general.obj.ExchangeRate) : oList) {
if (exchangeRate:factor = 2) factor := 10;
if (exchangeRate:factor = 3) factor := 100;
if (exchangeRate:factor = 4) factor := 1000;
if (exchangeRate:factor = 5) factor := 10000;
if ((useReverseQuotation = false and quotation = ExchangeRateQuotation.DIRECT) or
(useReverseQuotation = true and quotation = ExchangeRateQuotation.INDIRECT))
convertedAmount := (amount * factor) / exchangeRate:middleRate;
else
convertedAmount := (amount * exchangeRate:middleRate) / factor;
}
return convertedAmount;
}

getCorporateCurrency

Folgendes Beispiel aus der Aktivitätsdefinition help.getCorporateCurrency zeigt, wie die Customizing-Funktion Allgemein abgefragt werden kann, um die Leitwährung einer Firma zu bestimmen.

function create()
{
var p_organization := parameters.ORGANIZATION;
var r_corporateCurrency := getCorporateCurrency(loadOrganization(p_organization):guid);

result.PRIMARY_CURRENCY := loadCurrency(r_corporateCurrency):isoCode;
}

function getCorporateCurrency(org as Guid) as Guid
{
var corporateCurrency as Guid;
var baseFunction := getCustomizingValue("com.cisag.app.general.Base", loadOrganization(org):financialsOrganization);

if (not isNull(baseFunction)) {
corporateCurrency := baseFunction:corporateCurrencyGuid;
}
return corporateCurrency;
}

getCurrency1

Folgendes Beispiel aus der Aktivitätsdefinition help.getCurrency1 zeigt, wie die Customizing-Funktion Allgemein für den Mandanten abgefragt werden kann, um die erste Hauswährung aller Firmen zu bestimmen.

function create()
{
var r_currency1 := getCurrency1();

result.CURRENCY1 := loadCurrency(r_currency1):isoCode;
}

function getCurrency1() as Guid
{
var currency1 as Guid;
var company := loadOrganization(getCustomizingValue("com.cisag.app.General"):company);
var baseFunction := getCustomizingValue("com.cisag.app.general.Base", company:guid);

if (not isNull(baseFunction)) {
var combination := getByPrimaryKey(CisObject(com.cisag.app.multiorg.obj.DomesticCurrencyCombination), baseFunction:combination);
currency1 := combination:currency1;
}
return currency1;
}

getCurrency2

Folgendes Beispiel aus der Aktivitätsdefinition help.getCurrency2 zeigt, wie die Customizing-Funktion Allgemein für eine Firma abgefragt werden kann, um die zweite Hauswährung der Firma zu bestimmen.

function create()
{
var p_organization := parameters.ORGANIZATION;
var r_currency2 := getCurrency2(loadOrganization(p_organization):guid);
result.IS_NULL := isNull(r_currency2);
if (not isNull(r_currency2))
result.CURRENCY2 := loadCurrency(r_currency2):isoCode;
}

function getCurrency2(organization as Guid) as Guid
{
var currency2 as Guid;
var baseFunction := getCustomizingValue("com.cisag.app.general.Base", loadOrganization(organization):guid);

if (not isNull(baseFunction)) {
var combination := getByPrimaryKey(CisObject(com.cisag.app.multiorg.obj.DomesticCurrencyCombination), baseFunction:combination);
currency2 := combination:currency2;
}
return currency2;
}

getCurrency3

Folgendes Beispiel aus der Aktivitätsdefinition help.getCurrency3 zeigt, wie die Customizing-Funktion Allgemein für eine Firma abgefragt werden kann, um die dritte Hauswährung der Firma zu bestimmen.

function create()
{
var p_organization := parameters.ORGANIZATION;
var r_currency3 := getCurrency3(loadOrganization(p_organization):guid);

result.IS_NULL := isNull(r_currency3);
if (not isNull(r_currency3))
result.CURRENCY3 := loadCurrency(r_currency3):isoCode;
}

function getCurrency3(organization as Guid) as Guid
{
var currency3 as Guid;
var baseFunction := getCustomizingValue("com.cisag.app.general.Base", loadOrganization(organization):guid);

if (not isNull(baseFunction)) {
var combination := getByPrimaryKey(CisObject(com.cisag.app.multiorg.obj.DomesticCurrencyCombination), baseFunction:combination);
currency3 := combination:currency3;
}
return currency3;
}