In der Konfigurations-Datenbank sind beschreibende Daten für grundlegende Objekte wie Benutzer, Datenbanken und Server hinterlegt. Diese Objekte wer-den im ganzen System verwendet. Um diese Verwendungen aufzulösen, werden folgende Funktionen zur Verfügung gestellt:

• resolveRole
• userAbsent
• userFullName
• userGuid
• userMailAddress
• userName

Grundlegende Informationen zu den allgemeinen Funktionen der System-Skriptsprache erhalten Sie im Dokument System-Skriptsprache: Allgemeine Funktionen.

resolveRole

Folgendes Beispiel aus der Aktivitätsdefinition help.resolveRole gibt die Namen aller Benutzer zurück, die als Inhaber einer Workflowrolle zugeordnet sind:

function create()
{
var p_role := parameters.ROLE;
var r_users := "";

var users := resolveRole(p_role);
if (not isNull(users)) {
for (u : users)
r_users := r_users + " " + userName(u);
}
result.IS_NULL := isNull(users);
result.USERS := substring(r_users, 1);
}

userAbsent

Folgendes Beispiel aus der Aktivitätsdefinition help.userAbsent entfernt alle abwesenden Benutzer aus der Liste der Inhaber einer Workflowrolle:

function create()
{
var p_workflowRole := parameters.WORKFLOW_ROLE;
var p_time := parameters.TIME;
var p_from := parameters.FROM;
var p_until := parameters.UNTIL;
var r_nonAbsentUsers := "";

var holders := resolveRole(p_workflowRole);
if (not isNull(holders)) {
holders := removeAbsentUsers(holders, p_time, p_from, p_until);
for (user : holders) {
r_nonAbsentUsers := r_nonAbsentUsers + " " + userName(user);
}
}
result.NON_ABSENT_USERS := trim(r_nonAbsentUsers);
}

function removeAbsentUsers(p_users as Guid[], p_time as Timestamp, p_from as Timestamp, p_until as Timestamp) as Guid[]
{
var nonAbsentUsers as Guid[];

for (user : p_users) {
if (p_time <> UNDEFINED_DATE) {
if (not userAbsent(user, p_time))
add(nonAbsentUsers, user);
} else if (p_from <> UNDEFINED_DATE and p_until <> UNDEFINED_DATE) {
if (not userAbsent(user, p_from, p_until))
add(nonAbsentUsers, user);
} else {
if (not userAbsent(user))
add(nonAbsentUsers, user);
}
}
return nonAbsentUsers;
}

userFullName

Folgendes Beispiel aus der Aktivitätsdefinition help.userFullName gibt den vollständigen Namen eines Benutzers zurück:

function create()
{
var p_userName := parameters.USER_NAME;
var r_userFullName := "";

var userGuid := userGuid(p_userName);
if (userGuid <> INVALID_GUID)
r_userFullName := userFullName(userGuid);

result.USER_FULL_NAME := r_userFullName;
}

userGuid

Folgendes Beispiel aus der Aktivitätsdefinition help.userGuid gibt die Guid eines Benutzers zurück:

function create()
{
var p_userName := parameters.USER_NAME;
var r_userGuid := "";

var userGuid := userGuid(p_userName);
if (userGuid <> INVALID_GUID)
r_userGuid := cast(String, userGuid);

result.USER_GUID := r_userGuid;
}

Beispiel: Deaktivierte Benutzer entfernen

Folgendes Beispiel aus der Aktivitätsdefinition help.userDeactivated entfernt alle deaktivierten Benutzer aus der Liste der Inhaber einer Workflowrolle:

function create()
{
var p_workflowRole := parameters.WORKFLOW_ROLE;
var r_deactivatedUsers := "";

var holders := resolveRole(p_workflowRole);
if (not isNull(holders)) {
holders := removeDeactivatedUsers(holders);
for (user : holders) {
r_deactivatedUsers := r_deactivatedUsers + " " + userName(user);
}
}
result.DEACTIVATED_USERS := trim(r_deactivatedUsers);
}

function userDeactivated(p_user as Guid) as Boolean
{
var r_userDeactivated := false;
var user := getByPrimaryKey("CONFIGURATION", CisObject(com.cisag.sys.configuration.obj.User), p_user);
if (not isNull(user)) {
r_userDeactivated := user:deactivated;
}
return r_userDeactivated;
}

function removeDeactivatedUsers(p_users as Guid[]) as Guid[]
{
var activatedUsers as Guid[];
for (user : p_users) {
if (not userDeactivated(user))
add(activatedUsers, user);
}
return activatedUsers;
}

Beispiel: Nicht-interaktive Benutzer entfernen

Folgendes Beispiel aus der Aktivitätsdefinition help.userInteractive entfernt alle nicht-interaktiven Benutzer aus der Liste der Inhaber einer Workflowrolle:

const UserType as valueSet(com.cisag.sys.configuration.UserType);

function create()
{
var p_workflowRole := parameters.WORKFLOW_ROLE;
var r_nonInteractiveUsers := "";

var holders := resolveRole(p_workflowRole);
if (not isNull(holders)) {
holders := removeNonInteractiveUsers(holders);
for (user : holders) {
r_nonInteractiveUsers := r_nonInteractiveUsers + " " + userName(user);
}
}
result.NON_INTERACTIVE_USERS := trim(r_nonInteractiveUsers);
}

function userInteractive(p_user as Guid) as Boolean
{
var r_userInteractive := false;
var user := getByPrimaryKey("CONFIGURATION", CisObject(com.cisag.sys.configuration.obj.User), p_user);
if (not isNull(user)) {
r_userInteractive := user:type = UserType.INTERACTIVE;
}
return r_userInteractive;
}

function removeNonInteractiveUsers(p_users as Guid[]) as Guid[]
{
var interactiveUsers as Guid[];

for (user : p_users) {
if (userInteractive(user))
add(interactiveUsers, user);
}
return interactiveUsers;
}

userMailAddress

Folgendes Beispiel aus der Aktivitätsdefinition help.userMailAddress gibt die E-Mail-Adresse eines Benutzers zurück:

function create()
{
var p_userName := parameters.USER_NAME;
var r_userMailAddress := "";

var userGuid := userGuid(p_userName);
if (userGuid <> INVALID_GUID)
r_userMailAddress := userMailAddress(userGuid);

result.USER_MAIL_ADDRESS := r_userMailAddress;
}

userName

userName(userGuid("JOB"))

Folgendes Beispiel aus der Aktivitätsdefinition help.userName ermittelt den Namen des Benutzers, der den Partner des Mandanten erfasst hat:

function create()
{
  var r_userName := "";
  var company := loadOrganization(getCustomizingValue("com.cisag.app.General"):company);
  r_userName := userName(company:updateInfo.createUser);

  result.USER_NAME := r_userName;
}